lib/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69

{ inputs, ... }:

let
  lib = inputs.nixpkgs.lib;
  isDarwin = s: lib.strings.hasSuffix "-darwin" s;
in
{
  mkSystem =
    {
      host,
      username,
      system,
      overlays ? [ ],
      sharedModules ? [ ],
      extraModules ? [ ],
      extraArguments ? { },
    }:
    let
      darwinHost = isDarwin system;
      builder = if darwinHost then inputs.nix-darwin.lib.darwinSystem else inputs.nixpkgs.lib.nixosSystem;
      hmModule =
        if darwinHost then
          inputs.home-manager.darwinModules.home-manager
        else
          inputs.home-manager.nixosModules.home-manager;
      pkgs = import inputs.nixpkgs {
        inherit system overlays;
        config.allowUnfree = true;
      };
      hostDir = ../hosts/${host};
      hostCfg = hostDir + /configuration.nix;
      hostHome = hostDir + /home.nix;

      hmEnabled = builtins.pathExists hostHome;
      modules = [
        hostCfg
      ]
      ++ lib.optionals darwinHost [ inputs.mac-app-util.darwinModules.default ]
      ++ [
        {
          nix.settings.experimental-features = [
            "nix-command"
            "flakes"
          ];
          nixpkgs.overlays = overlays;
        }
      ]
      ++ lib.optionals hmEnabled [
        hmModule
        {
          home-manager.useGlobalPkgs = true;
          home-manager.useUserPackages = true;
          home-manager.backupFileExtension = "backup";
          home-manager.extraSpecialArgs = { inherit inputs pkgs; };
          home-manager.users.${username} = import hostHome;
          home-manager.sharedModules = sharedModules;
        }
      ]
      ++ extraModules;
    in
    builder {
      system = system;
      specialArgs = {
        inherit inputs pkgs;
      }
      // extraArguments;
      modules = modules;
    };
}