modules/system/quickshell/shell.qml


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

//@ pragma UseQApplication
import Quickshell
import QtQuick
import Quickshell.Io
import Quickshell.Wayland

ShellRoot {
    Component.onCompleted: {
        Qt.application.font.family = "Inter";
        Qt.application.font.hintingPreference = Font.PreferNoHinting;
        Qt.application.font.styleStrategy = Font.NoSubpixelAntialias;
    }

    Variants {
        model: Quickshell.screens

        Bar {
            required property var modelData
            screen: modelData
        }
    }

    Variants {
        model: Quickshell.screens

        Background {
            required property var modelData
            screen: modelData
        }
    }

    Notifications {}

    VolumeOSD {}
    Polkit {}
    Launcher {}

    LockContext {
        id: lockContext
        onUnlocked: {
            sessionLock.locked = false;
        }
    }

    WlSessionLock {
        id: sessionLock

        WlSessionLockSurface {
            LockSurface {
                anchors.fill: parent
                context: lockContext
            }
        }
    }

    IpcHandler {
        target: "bar"
        function toggleLauncher() {
            GlobalState.toggle("Launcher");
        }

        function lock() {
            lockContext.reset();
            sessionLock.locked = true;
        }
    }
}