blob: 5472f4240f8c41b23634c04a5dc05460067bbe3b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
|
{
description = "Flake for site deployment";
inputs = {
nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
flake-utils.url = "github:numtide/flake-utils";
};
outputs =
{
self,
nixpkgs,
flake-utils,
}:
flake-utils.lib.eachDefaultSystem (
system:
let
pkgs = import nixpkgs { inherit system; };
site = pkgs.buildNpmPackage {
pname = "site";
version = "0.1.0";
src = ./.;
npmDepsHash = "sha256-a6jp/1FU3J8bUOPehfZP6dVeCcqSd0QZbjwu340YXBE=";
buildPhase = ''
runHook preBuild
npm run build
runHook postBuild
'';
installPhase = ''
runHook preInstall
mkdir -p $out/share/web
cp -r .next/standalone/. $out/share/web/
mkdir -p $out/share/web/.next
cp -r .next/static $out/share/web/.next/
cp -r public $out/share/web/
runHook postInstall
'';
};
in
{
packages = {
default = site;
};
devShells = {
default = pkgs.mkShell {
buildInputs = with pkgs; [
nodejs_22
corepack_22
nodePackages.typescript-language-server
nodePackages.vscode-langservers-extracted
];
shellHook = ''
export PATH="$PWD/node_modules/.bin:$PATH"
echo "Development environment loaded."
node --version
exec zsh
'';
};
};
}
)
// {
nixosModules.default =
{
lib,
config,
pkgs,
...
}:
let
cfg = config.services.site;
inherit (lib)
mkIf
mkEnableOption
mkOption
types
;
in
{
options.services.site = {
enable = mkEnableOption "Serve the built Next.js site using systemd";
domain = mkOption {
type = types.str;
description = "Domain to serve.";
};
port = mkOption {
type = types.port;
default = 3000;
description = "Port to expose on the host.";
};
package = mkOption {
type = types.package;
description = "The site package to run.";
default = self.packages.${pkgs.system}.default;
};
sslCertificate = mkOption {
type = types.nullOr types.path;
default = null;
description = "Path to TLS certificate (PEM).";
};
sslCertificateKey = mkOption {
type = types.nullOr types.path;
default = null;
description = "Path to TLS private key (PEM).";
};
};
config = mkIf cfg.enable {
assertions = [
{
assertion = (cfg.sslCertificate == null) == (cfg.sslCertificateKey == null);
message = "services.site: sslCertificate and sslCertificateKey must be set together.";
}
];
systemd.services.site = {
description = "Next.js site service";
wantedBy = [ "multi-user.target" ];
after = [ "network.target" ];
serviceConfig = {
ExecStart = "${pkgs.nodejs}/bin/node ${cfg.package}/share/web/server.js";
WorkingDirectory = "${cfg.package}/share/web";
User = "nextjs";
Group = "nextjs";
Restart = "always";
# Hardening
DynamicUser = true;
PrivateTmp = true;
ProtectSystem = "strict";
ProtectHome = true;
NoNewPrivileges = true;
Environment = [
"NODE_ENV=production"
"PORT=${toString cfg.port}"
"HOSTNAME=127.0.0.1"
];
};
};
services.nginx = {
enable = true;
virtualHosts.${cfg.domain} =
let
useTLS = (cfg.sslCertificate != null) && (cfg.sslCertificateKey != null);
in
{
forceSSL = useTLS;
sslCertificate = mkIf useTLS cfg.sslCertificate;
sslCertificateKey = mkIf useTLS cfg.sslCertificateKey;
locations."/" = {
proxyPass = "http://127.0.0.1:${toString cfg.port}";
proxyWebsockets = true;
};
};
};
};
};
};
}
|
