flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109

{
  description = "Dungeon project dev environment with Raylib 5.5, raytmx, and hoxml";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
  };

  outputs =
    { self, nixpkgs }:
    let
      supportedSystems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];

      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
    in
    {
      packages = forAllSystems (
        system:
        let
          pkgs = import nixpkgs { inherit system; };

          myRaylib = pkgs.raylib.overrideAttrs (oldAttrs: {
            version = "5.5";
            src = pkgs.fetchFromGitHub {
              owner = "raysan5";
              repo = "raylib";
              rev = "c1ab645ca298a2801097931d1079b10ff7eb9df8";
              hash = "sha256-J99i4z4JF7d6mJNuJIB0rHNDhXJ5AEkG0eBvvuBLHrY=";
            };
          });

          raytmx = pkgs.stdenv.mkDerivation {
            pname = "raytmx";
            version = "d4e09bc";
            src = pkgs.fetchFromGitHub {
              owner = "luphi";
              repo = "raytmx";
              rev = "d4e09bcfa7a2fb553853b15b25f0fa74f6cb8912";
              hash = "sha256-uahAiQ2HucRV86/ZOoYw03mhd8hLVcGPmheG5cy44oU=";
            };
            installPhase = ''
              mkdir -p $out/include
              cp raytmx.h $out/include/
            '';
          };

          hoxml = pkgs.stdenv.mkDerivation {
            pname = "hoxml";
            version = "12938da";
            src = pkgs.fetchFromGitHub {
              owner = "luphi";
              repo = "hoxml";
              rev = "12938da4ce3217ce7986acfc7745744acb7c5dfb";
              hash = "sha256-h5fouCX0+GRtEnJ5KlaIyDTj5I0oFmlUj8NsvjKzGho=";
            };
            installPhase = ''
              mkdir -p $out/include
              cp hoxml.h $out/include/
            '';
          };

        in
        {
          default = pkgs.stdenv.mkDerivation {
            pname = "dungeon";
            version = "0.1.0";

            src = ./.;

            buildInputs = [
              myRaylib
              raytmx
              hoxml
            ];

            nativeBuildInputs = [
              pkgs.pkg-config
              pkgs.cmake
            ];

            cmakeFlags = [ "-DUSE_NIX=ON" ];
          };
        }
      );

      devShells = forAllSystems (
        system:
        let
          pkgs = import nixpkgs { inherit system; };
        in
        {
          default = pkgs.mkShell {
            inputsFrom = [ self.packages.${system}.default ];
          };
        }
      );

      apps = forAllSystems (system: {
        default = {
          type = "app";
          program = "${self.packages.${system}.default}/bin/dungeon_game";
        };
      });
    };
}